Amiga Magazin: Amiga-CD 1996 September & October/Amiga-CD 1996 #9-10.iso/aminet/7-96/lha-archive/aspell.lha/AlphaSpell/Install

Text File | 1996-05-10 | 11KB | 433 lines

; Installation script for AlphaSpell

(transcript "Installing AlphaSpell ...")

; Messages

(set #intro (cat
    "This script will install the spelling checker AlphaSpell, "
    "an English dictionary, the AlphaSpell GUI, which will let AlphaSpell "
    "work with a text editor, and MUISpell, a stand-alone GUI for AlphaSpell "
    "that requires MUI.\n\nYou may skip any stage of the installation."
) )

(set #where (cat
    "This script will create a drawer called AlphaSpell and put everything "
    "in it. Where do you want to create this drawer?"
))

(set #arexxport (cat
    "Andy Cook's arexxport.library\n\nThis library is required for "
    "AlphaSpell's arexx port, and it is required for Varexx, which makes "
    "the AlphaSpell GUI possible."
))

(set #rexxtricks (cat
    "Jürgen Kohrmeyer's rexxtricks.library\n\nThis library is required for "
    "the AlphaSpell GUI."
))

(set #gui (cat
    "Would you like to install the AlphaSpell GUI? This is an interface that "
    "lets you use AlphaSpell with your text editor."
))

(set #mui (cat
    "Would you like to install MUISpell? This is a stand-alone Magic User "
    "Interface that lets you spell check without the aid of a text editor."
))

(set #editors (cat
    "Which text editors do you want to install scripts for? The stars "
    "indicate how well the AlphaSpell GUI works with each editor."
))

(set #disk (cat
    "It is recommended that you install AlphaSpell to your hard drive. But "
    "AlphaSpell will also work off of a floppy disk. How do you want to "
    "install AlphaSpell?"
))

(message #intro)

; Install Alphaspell

(complete 0)

(if (not (exists "AlphaSpell:" (noreq)))
    (if
        (askbool
            (prompt #disk)
            (help @askbool-help)
            (choices "Hard Drive" "Floppy Disk")
        )
        (
            (set #dest
                (tackon
                    (askdir
                        (prompt #where)
                        (help @askdir-help)
                        (default "Work:")
                    )
                    "AlphaSpell"
                )
            )
            (makedir #dest (infos))
            (makeassign "AlphaSpell" #dest)
            (startup "AlphaSpell"
                (prompt "Adding assign to S:User-Startup")
                (help @startup-help)
                (command (cat "Assign AlphaSpell: " #dest))
            )
        )
        (askdisk
            (prompt "Please insert a disk labeled AlphaSpell")
            (help @askdisk-help)
            (dest "AlphaSpell")
        )
    )
)
(set @default-dest "AlphaSpell:")

(set cputype (+(database "CPU")) )

(if (< cputype 68020)
    (set #src "68000/AlphaSpell")
    (set #src "68020/AlphaSpell")
)

(copyfiles
    (prompt "Copying AlphaSpell")
    (help @copyfiles-help)
    (source #src)
    (newname "AlphaSpell")
    (dest "AlphaSpell:")
    (confirm)
)

(copyfiles
    (prompt "Copying AlphaSpell's icon")
    (help @copyfiles-help)
    (source "AlphaSpell.info")
    (dest "AlphaSpell:")
    (confirm)
)

; Install Documentation

(complete 16)

(makedir "AlphaSpell:Docs" (infos))

(copyfiles
    (prompt "Copying AlphaSpell's Documentation")
    (help @copyfiles-help)
    (source "Docs/")
    (dest "AlphaSpell:Docs/")
    (confirm)
    (infos)
    (all)
)

; Install Dictionary

(complete 33)

(makedir "AlphaSpell:Dict")
(makedir "AlphaSpell:Dict/English")

(copyfiles
    (prompt "Copying AlphaSpell's Dictionaries")
    (help @copyfiles-help)
    (source "Dict/English/")
    (dest "AlphaSpell:Dict/English/")
    (confirm)
    (all)
)

; Install the AlphaSpell GUI

(complete 49)

(if
    (askbool
        (prompt #gui)
        (help @askbool-help)
    )
    (
        (set options
            (askoptions
                (prompt #editors)
                (help @askoptions-help)
                (choices
                    "AmokEd *"
                    "Annotate **"
                    "BlacksEditor ****"
                    "DME *"
                    "Ed ***"
                    "Emacs ****"
                    "FrexxEd ****"
                    "GoldEd ****"
                    "SkoEd *"
                    "Textra ****"
                    "TJM DME ****"
                    "TKEd"
                    "TurboText ****"
                    "XDME ****"
                )
                (default 0)
            )
        )

        (set #rexxdir "AlphaSpell:REXX")
        (makedir #rexxdir)

        (if (bitand options $01)
            (copyfiles
                (prompt "Copying ARexx script")
                (help @copyfiles-help)
                (source "Interfaces/AmokEd/")
                (dest #rexxdir)
                (confirm)
                (all)
            )
        )

        (if (bitand options $02)
            (copyfiles
                (prompt "Copying ARexx script")
                (help @copyfiles-help)
                (source "Interfaces/Annotate/")
                (dest #rexxdir)
                (confirm)
                (all)
            )
        )

        (if (bitand options $04)
            (copyfiles
                (prompt "Copying ARexx script")
                (help @copyfiles-help)
                (source "Interfaces/BlacksEditor/")
                (dest #rexxdir)
                (confirm)
                (all)
            )
        )

        (if (bitand options $08)
            (copyfiles
                (prompt "Copying ARexx script")
                (help @copyfiles-help)
                (source "Interfaces/DME/")
                (dest #rexxdir)
                (confirm)
                (all)
            )
        )

        (if (bitand options $10)
            (copyfiles
                (prompt "Copying ARexx script")
                (help @copyfiles-help)
                (source "Interfaces/Ed/")
                (dest #rexxdir)
                (confirm)
                (all)
            )
        )

        (if (bitand options $20)
            (copyfiles
                (prompt "Copying ARexx script")
                (help @copyfiles-help)
                (source "Interfaces/Emacs/")
                (dest #rexxdir)
                (confirm)
                (all)
            )
        )

        (if (bitand options $40)
            (copyfiles
                (prompt "Copying ARexx script")
                (help @copyfiles-help)
                (source "Interfaces/FrexxEd/")
                (dest #rexxdir)
                (confirm)
                (all)
            )
        )

        (if (bitand options $80)
            (copyfiles
                (prompt "Copying ARexx script")
                (help @copyfiles-help)
                (source "Interfaces/GoldEd/")
                (dest #rexxdir)
                (confirm)
                (all)
            )
        )

        (if (bitand options $100)
            (copyfiles
                (prompt "Copying ARexx script")
                (help @copyfiles-help)
                (source "Interfaces/SkoEd/")
                (dest #rexxdir)
                (confirm)
                (all)
            )
        )

        (if (bitand options $200)
            (copyfiles
                (prompt "Copying ARexx script")
                (help @copyfiles-help)
                (source "Interfaces/Textra/")
                (dest #rexxdir)
                (confirm)
                (all)
            )
        )

        (if (bitand options $400)
            (copyfiles
                (prompt "Copying ARexx script")
                (help @copyfiles-help)
                (source "Interfaces/TJM_DME/")
                (dest #rexxdir)
                (confirm)
                (all)
            )
        )

        (if (bitand options $800)
            (copyfiles
                (prompt "Copying ARexx script")
                (help @copyfiles-help)
                (source "Interfaces/TKEd/")
                (dest #rexxdir)
                (confirm)
                (all)
            )
        )

        (if (bitand options $1000)
            (copyfiles
                (prompt "Copying ARexx script")
                (help @copyfiles-help)
                (source "Interfaces/TurboText/")
                (dest #rexxdir)
                (confirm)
                (all)
            )
        )

        (if (bitand options $2000)
            (copyfiles
                (prompt "Copying ARexx script")
                (help @copyfiles-help)
                (source "Interfaces/XDME/")
                (dest #rexxdir)
                (confirm)
                (all)
            )
        )

        (copyfiles
            (prompt "Copying ASpell.gui")
            (help @copyfiles-help)
            (source "ASpell.gui")
            (dest "AlphaSpell:")
            (confirm)
            (infos)
        )

        (if (= @language "deutsch")
            (
                (makedir "AlphaSpell:Catalogs")
                (copyfiles
                    (prompt "Deutsches Katalog")
                    (help @copyfiles-help)
                    (source "Catalogs/ASpell.deutsch")
                    (dest "AlphaSpell:Catalogs/")
                    (confirm)
                    (all)
                )
            )
        )

        (copylib
            (prompt #rexxtricks)
            (help @copylib-help)
            (source "libs/rexxtricks.library")
            (dest "LIBS:")
            (confirm)
        )

        (copylib
            (prompt "Andy Cook's Varexx. Required by the AlphaSpell GUI.")
            (help @copylib-help)
            (source "bin/varexx")
            (dest "SYS:rexxc/")
            (confirm)
        )
    )
)

; Install Libraries

(complete 66)

(copylib
    (prompt #arexxport)
    (help @copylib-help)
    (source "libs/arexxport.library")
    (dest "LIBS:")
    (confirm)
)

; Install MUISpell

(complete 82)

(if
    (askbool
        (prompt #mui)
        (help @askbool-help)
    )
    (
        (makedir "AlphaSpell:MUISpell" (infos))
        (copyfiles
            (prompt "Installing MUISpell")
            (help @copylib-help)
            (source "MUISpell/MUISpell")
            (dest "AlphaSpell:MUISpell/")
            (confirm)
        )

        (makedir "AlphaSpell:MUISpell/Docs" (infos))
        (copyfiles
            (prompt "Copying MUISpell's Documentation")
            (help @copyfiles-help)
            (source "MUISpell/Docs/")
            (dest "AlphaSpell:MUISpell/Docs/")
            (confirm)
            (all)
        )

        (if (exists "MUI:MUI" (noreq))
            (if (> 917523 (getversion "MUI:MUI"))
                (message "You may need to update MUI to use MUISpell.")
            )
            (message "You need MUI installed to use MUISpell.")
        )
    )
)

(complete 100)

(exit)